#From Thompson SG, Nixon RM and Grieve R, Addressing the issues that arise in analysing multicentre cost
 data, with application to a multinational study, Health Economics, 2005

model{

#The Generalized linear mixed model regression
for(i in 1:N){
    totcos[i]~dgamma(shape[centre[i]],rate[i])    
    rate[i]<-shape[centre[i]]/ztheta[i]
    log(ztheta[i])<-lmu[centre[i]]+lIncont[centre[i]]*incont[i]
}


#Random effects
for(j in 1:13){
    lIncont[j]~dnorm(mu.lincont, tau.lincont)
}
tau.lincont<-1/ss.lincont
ss.lincont<-s.lincont*s.lincont

#Likelihood
for(i in 1:N){
zloglik[i]<- -loggam(shape[centre[i]]) + shape[centre[i]]*log(rate[i]) + (shape[centre[i]]-1)*log(totcos[i]) - rate[i]*totcos[i]
}
loglik<--2*sum(zloglik[])

#Priors
for(j in 1:13){
    shape[j]~dunif(0,10)
    lmu[j]~dunif(-10,10)
}
mu.lincont~dunif(-10,10)
s.lincont~dunif(0.01,20)


#Unused variables
paraly.dum<-mean(paraly[])
stype2.dum<-mean(stype2[])
stype3.dum<-mean(stype3[])
living2.dum<-mean(living2[])
living3.dum<-mean(living3[])
gdp.dum<-mean(gdp[])
}