#  8.8.  HIV:  evidence synthesis.


model;
{
# set data
r[1]<-11044;      r[2]<-12;     r[3]<-252;       r[4]<-10;     r[5]<-74;            r[6]<-254
n[1]<-104577;  n[2]<-882;  n[3]<-15428;  n[4]<-473;  n[5]<-136139;  n[6]<-102287

r[7]<-43;   r[8]<-4;     r[9]<-87;     r[10]<-12;   r[11]<-14;     r[12]<-5
n[7]<-60;  n[8]<-17;  n[9]<-254;  n[10]<-15;  n[11]<-118;  n[12]<-31
# SET PRIORS
a ~ dbeta( 1,2)
z ~ dbeta (1,1)
b <- z * (1-a) # sets constraint (1-a-b > 0)
c ~ dbeta (1,1)
d ~ dbeta (1,1)
e ~ dbeta (1,1)
f ~ dbeta (1,1)
g ~ dbeta (1,1)
h ~ dbeta(1,1)
w ~ dbeta(1,1)
# VECTOR p[1:12] HOLDS THE EXPECTED PROBABILITIES FOR EACH DATA POINT
p[1] <- a
p[2] <- b
p[3] <- c
p[4] <- d
p[5] <- (d*b + e*(1-a-b))/(1- a)
p[6] <- c*a + d*b + e*(1-a-b)
p[7] <- f*c*a / (f*c*a + g*d*b + h*e*(1-a-b))
p[8] <- g*d*b / (g*d*b + h*e*(1-a-b))
p[9] <- (f*c *a + g*d*b + h*e*(1-a-b)) / p[6]
p[10] <- g
p[11] <- w
p[12] <- d*b/(d*b+e*(1-a-b)) + w*e*(1-a-b)/(d*b + e*(1-a-b))

x[1]<- 10000*(1-a-b) *(1-e*h)  # num additional tests/10000
x[2] <-10000*(1-a-b) *e*(1-h)  # num additional cases/10000
 
for(i in 1:3){  #      change this to 4 to include all data
r[i] ~ dbin(p[i],n[i])
}
for(i in 5:12){
r[i] ~ dbin(p[i],n[i])
}

# calculate predictive P-values, using normal approximation to speed up sampling
for(i in 1:12){  #   
t[i]<-n[i]/(p[i]*(1-p[i]))  # normal precision    
p.rep[i] ~ dnorm(p[i],t[i])
p.smaller[i]<-step(r[i]/n[i] - p.rep[i])
}

}