Radiocarbon calibration
- Case Study I - 
St Veit-Klinglberg, Austria - stratification
Buck CE, Cavanagh WG & Litton CD (1996) Bayesian approach to interpreting archaeological data.  Wiley: Chichester p218-226
See also Buck CE, Litton CD & Shennan SJ (1994) A case study in combining radiocarbon and archaeological information: the Early Bronze Age settlement of St Veit-Klinglberg, Lan Salzburg, Austria. Germania 2 427-447

model{ 
	theta[1] ~ dunif(theta[2],theta.max)
	theta[2] ~ dunif(theta[3],theta[1])
	theta[3] ~ dunif(theta[9],theta[2])
	theta[4] ~ dunif(theta[9],theta.max)
	theta[5] ~ dunif(theta[7],theta.max)
	theta[6] ~ dunif(theta[7],theta.max)
	theta[7] ~ dunif(theta[9],theta7max)
	theta7max <- min(theta[5], theta[6])
	theta[8] ~ dunif(theta[9],theta.max)
	theta[9] ~ dunif(theta[10],theta9max)
	theta9max <-min( min(theta[3], theta[4]),  min(theta[7], theta[8]))
	theta[10] ~ dunif(theta[11],theta[9])
	theta[11] ~ dunif(0,theta[10])
	
	bound[1] <- ranked(theta[1:8],  8)
	bound[2] <- ranked(theta[1:8], 1)
	bound[3] <- ranked(theta[9:11], 3)
	bound[4] <- ranked(theta[9:11], 1)
	
	for (j in 1 : 5){
		theta[j + 11] ~ dunif(0, theta.max)
		within[j, 1] <- 1 - step(bound[1] - theta[j + 11])
		for (k in 2 : 4){
			within[j, k] <- step(bound[k - 1] - theta[j + 11]) - step(bound[k] - theta[j + 11])
		}
		within[j, 5] <- step(bound[4] - theta[j + 11])
	}


	for (i in 1:nDate){
		X[i] ~ dnorm(mu[i], tau[i])
		tau[i] <- 1/pow(sigma[i],2)
		mu[i] <- interp.lin(theta[i], calBP[], C14BP[])

# monitor the following variable to smooth density of theta
		theta.smooth[i] <- 10 * round(theta[i] / 10)
	}
}

Data

list(nDate=16, theta.max=21000,
	X=       c(3275, 3270, 3400, 3190, 3420, 3370, 3435, 3160, 3340, 3270, 3200, 3390, 3480, 3250, 3115, 3460), 
	sigma=c(  75,     80,     75,    75,     65,     75,    60,    70,     80,    75,    70,     80,    75,    75,     70,    70))

click arrow for calibration curve data

Inits

list(theta=c(3500, 3500, 3500, 3500, 3500, 3500, 3500, 3500, 3500, 3500, 3500, 3500, 3500, 3500, 3500, 3500))



	 node	 mean	 sd	 MC error	
	within[1,1]	0.1869	0.3898	0.004748	
	within[1,2]	0.7512	0.4323	0.005902	
	within[1,3]	0.0239	0.1527	0.001711	
	within[1,4]	0.0343	0.182	0.002705	
	within[1,5]	0.0037	0.06071	6.139E-4	
	within[2,1]	0.5228	0.4995	0.006329	
	within[2,2]	0.4718	0.4992	0.006467	
	within[2,3]	0.0019	0.04355	5.064E-4	
	within[2,4]	0.0034	0.05821	7.683E-4	
	within[2,5]	1.0E-4	0.009999	1.0E-4	
	within[3,1]	0.0057	0.07528	9.239E-4	
	within[3,2]	0.5221	0.4995	0.008287	
	within[3,3]	0.0996	0.2995	0.003068	
	within[3,4]	0.2748	0.4464	0.007434	
	within[3,5]	0.0978	0.297	0.003884	
	within[4,1]	0.0	0.0	1.0E-12	
	within[4,2]	0.0416	0.1997	0.002428	
	within[4,3]	0.0278	0.1644	0.001661	
	within[4,4]	0.2778	0.4479	0.006075	
	within[4,5]	0.6528	0.4761	0.006834	
	within[5,1]	0.4432	0.4968	0.00613	
	within[5,2]	0.5496	0.4975	0.006229	
	within[5,3]	0.0042	0.06467	7.132E-4	
	within[5,4]	0.0029	0.05377	6.243E-4	
	within[5,5]	1.0E-4	0.009999	1.0E-4